Lidt om beregning af placering

Af og til har man behov for at finde et tals placering i en talrække, fx i forbindelse med resultater el. lignende. Ovenstående figur viser nogle point, som forskellige deltagere har opnået i konkurrence. Flest point giver højeste placering. Placeringen er beregnet ved hjælp af formlen

=PLADS(B2;$B$2:$B$11)

i celle C2. Denne formel er så kopieret nedad. Det er forholdsvis nemt at håndtere, og placeringen er nem at sortere efter, hvis det ønskes. Hvis der er to eller flere, der har opnået samme pointtal, tildeles de samme placering, og den næste får så en placering, der svarer til, at de havde haft hver sin placering. Måske en lidt kringlet forklaring, men figuren nedenfor illustrerer forhåbentlig, hvad jeg mener. Figuren er sorteret efter placeringen for at gøre det mere overskueligt

Som det fremgår af figuren, er der nu tre, der har samme pointtal på tredjepladsen. Til gengæld er der ingen, der har nummer fire og fem, så den næste i rækkefølgen bliver nummer 6. Det vil typisk være den måde, man håndterer placeringer på i de fleste konkurrencer.

Af og til er der imidlertid behov for at gøre det på andre måder, og her har jeg kendskab til to varianter. En, hvor man ønsker at det samme resultater udløser forskellig placering, og en, hvor man ønsker, at samme resultat udløser samme placering, men hvor der ikke springes placeringer over. I den første variant skulle der altså have stået henholdsvis 3, 4 og 5 ud for alle de deltagere, der havde opnået 654 point og den næste deltager skulle så have været 6, som i figuren. I det andet tilfælde skulle placeringen have været 3 ved alle de, opnåede 654 point, men den næste deltager (445) skulle så have haft nummer 4.

Den første variant kan løses med formlen

=PLADS(B2;$B$2:$B$11;0)+TÆL.HVIS($B$2:B2;B2)-1

Når denne indsættes i B2 og kopieres ned, giver det følgende resultat. Igen er der sorteret efter placering. Pladsfunktionen suppleres her med dunktionen TÆL.HVIS(), der tæller om der er flere forekomster af samme pointtal.

Som det fremgår har de tre deltagere med samme pointtal nu hver sin placering, idet den første med et givent pointtal får den laveste placering, den sidste får den højeste.

Variant nummer to kan løses med en formel, der slet ikke anvender funktionen PLADS(), men derimod de tre funktioner SUM(), HVIS() og TÆL.HVIS()

=SUM(HVIS(B2<$B$2:$B$11;1/TÆL.HVIS($B$2:$B$11;$B$2:$B$11)))+1

Denne formel skal indtastes som en matrix-formel. Der skal altså afsluttes med Ctrl+Skift+Enter inden formlen kopieres. Nu ser resultatet således ud

Der er nu tre med samme placering (nummer 3) og den næste får nummer 4.

I den oprindelige pladsformel kan man "sortere" omvendt, altså laveste point giver højeste placering ved at ændre formlen til

=PLADS(B2;$B$2:$B$11;1)

Det tilføjede argument fortæller netop, at der skal sorteres i modsat orden. I den første variant løses denne opgave på samme måde ved at tilføje det ekstra argument til PLADS funktionen

=PLADS(B2;$B$2:$B$11;1)+TÆL.HVIS($B$2:B2;B2)-1

Og også variant to kan sorteres omvendt. Her gøres det ved simpelthen at "vende" ulighedstegnet i HVIS funktionen:

=SUM(HVIS(B2>$B$2:$B$11;1/TÆL.HVIS($B$2:$B$11;$B$2:$B$11)))+1

Husk, at der fortsat skal afsluttes med Ctrl+Skift+Enter i denne variant.

- Tilbage til Excel -